1 REM *********************************
2 REM *           W.I.C.P.            *
3 REM *********************************
4 REM *(C)OPYRIGHT 1995 BY PHOENIX OF *
5 REM *HIGH-TECH AND ERROR2000!       *
6 REM *********************************
7 REM *                               *
8 REM *HOPE YOU HAVE FUN WITH THIS PRG*
9 REM *********************************
10 ME$(1,1)="PLEASE":ME$(1,2)="PRESS ":ME$(1,3)="[210]ETURN"
12 POKE53280,.:POKE53281,.:PRINTCHR$(8)CHR$(14)
16 REM ++++++++++++++++++++++
17 REM + WINDOW VORBEREITEN +
18 REM ++++++++++++++++++++++
20 ZE=3:SP=3:BR=6:HO=5:GOSUB10000
21 REM ++++++++++++++++++++
22 REM + MENUE-AUSWAEHLEN +
23 REM ++++++++++++++++++++
30 ZA=3:M=1:GOSUB17000
31 REM +++++++++
32 REM + INPUT +
33 REM +++++++++
40 ZE=15:SP=15:LA=18:GOSUB20000
50 REM --------------------------------
60 ZE=2:SP=2:BR=LEN(F$)+8:HO=1:GOSUB10000:POKE211,3:POKE214,3:SYS58640
70 PRINT"[200]ALLO ";F$;" !"
80 END
90 REM ++++++++++++++++++++++++++++++++
10000 REM ********************
10010 REM * WINDOW ERSTELLEN *
10020 REM ********************
10030 GOSUB15000:REM BILDSCHIRM RETTEN
10040 POKE1024+40*ZE+SP,112:IFBR=0THEN10060
10050 FORI=1TOBR:POKE1024+40*ZE+SP+I,64:NEXT
10060 POKE1024+40*ZE+SP+BR+1,110:IFHO=0THEN10090
10070 FORI=1TOHO:POKE1024+40*(I+ZE)+SP,93:FORJ=1TOBR:POKE1024+40*(I+ZE)+SP+J,32
10080 NEXT:POKE1024+40*(I+ZE)+SP+J,93:NEXT
10090 POKE1024+40*(ZE+HO+1)+SP,109:IFBR=0THEN10110
10100 FORI=1TOBR:POKE1024+40*(ZE+HO+1)+SP+I,64:NEXT
10110 POKE1024+40*(ZE+HO+1)+SP+BR+1,125
10120 RETURN
15000 REM ---------------------
15010 REM - BILDSCHIRM RETTEN -
15020 REM ---------------------
15030 FORI=0TO(HO+1)
15040 FORJ=0TO(BR+1)
15050 POKE49152+40*I+J,PEEK(1024+40*(I+ZE)+(J+SP))
15060 NEXTJ,I
15070 RETURN
16000 REM ---------------------------
16010 REM - BILDSCHIRM ZURUECKHOLEN -
16020 REM ---------------------------
16030 FORI=0TO(HO+1)
16040 FORJ=0TO(BR+1)
16050 POKE(1024+40*(I+ZE)+(J+SP)),PEEK(49152+40*I+J)
16060 NEXTJ,I
16070 RETURN
17000 REM ********************
17010 REM * STRINGS AUSGEBEN *
17020 REM ********************
17030 FORI=1TOZA
17040 POKE211,SP+1:POKE214,ZE+2*I-1:SYS58640
17050 PRINTME$(M,I):NEXT
18000 REM -----------------
18010 REM - MENUE-AUSWAHL -
18020 REM -----------------
18030 I=1:U=1
18040 POKE211,SP+1:POKE214,ZE+2*I-1:SYS58640
18050 PRINT"";ME$(M,U);"[146]"
18060 GETA$:IFA$=""THEN18060
18070 IFA$="[145]"THENGOSUB19050:I=I-1:U=U-1:IFI<1THENI=ZA:U=ZA:GOTO18040
18080 IFA$=""THENGOSUB19050:I=I+1:U=U+1:IFI>ZATHENI=1:U=1:GOTO18040
18090 IFA$="_"THENS=1:RETURN
19000 IFA$=CHR$(13)THENGOSUB16000:RETURN
19010 GOTO18040
19050 REM ------------------------
19060 REM - ALTES MENUE LOESCHEN -
19070 REM ------------------------
19080 POKE211,SP+1:POKE214,ZE+2*I-1:SYS58640:PRINTME$(M,U):RETURN
20000 REM *****************
20010 REM * INPUT-ROUTINE *
20020 REM *****************
20030 REM *** EINGABEFELD ANFANG ***
20040 SP=SP-1:ZE=ZE-1
20050 BR=LA+1:HO=1
20060 GOSUB10000:REM*** EINGABEFELD ***
20070 REM *** EINGABEFELD ENDE ***
20080 POKE211,SP+1:POKE214,ZE+1:SYS58640
20090 PRINT"[164]";:F$="":H=0
20100 GETA$:IFA$=""THEN20100
20110 IFA$=CHR$(13)THENGOSUB16000:RETURN
20120 IFA$="_"THENS=1:RETURN
20130 IFA$=CHR$(20)ANDH>0THENF$=LEFT$(F$,H-1):H=H-1:PRINT"[157][157]  ";:GOTO20200
20140 IFA$="[147]"THENF$="":H=0:GOTO20190
20150 IFA$<" "ORA$>"[218]"THEN20100
20160 IFA$>CHR$(122)ANDA$<CHR$(192)THEN20100
20170 IFH=LATHEN20100
20180 F$=F$+A$:H=H+1:GOTO20200
20190 POKE211,SP+1:POKE214,ZE+1:SYS58640:FORI=1TOLA+1:PRINT" ";:NEXT
20200 POKE211,SP+1:POKE214,ZE+1:SYS58640:PRINTF$"[164]";:GOTO20100